modified maps

modified maps

Assets/NatureStarterKit2/Standard Assets/Effects/ToonShading/Shaders/ToonBasic.shader

@@ -0,0 +1,65 @@
+// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
+
+Shader "Toon/Basic" {
+	Properties {
+		_Color ("Main Color", Color) = (.5,.5,.5,1)
+		_MainTex ("Base (RGB)", 2D) = "white" {}
+		_ToonShade ("ToonShader Cubemap(RGB)", CUBE) = "" { }
+	}
+
+
+	SubShader {
+		Tags { "RenderType"="Opaque" }
+		Pass {
+			Name "BASE"
+			Cull Off
+			
+			CGPROGRAM
+			#pragma vertex vert
+			#pragma fragment frag
+			#pragma multi_compile_fog
+
+			#include "UnityCG.cginc"
+
+			sampler2D _MainTex;
+			samplerCUBE _ToonShade;
+			float4 _MainTex_ST;
+			float4 _Color;
+
+			struct appdata {
+				float4 vertex : POSITION;
+				float2 texcoord : TEXCOORD0;
+				float3 normal : NORMAL;
+			};
+			
+			struct v2f {
+				float4 pos : SV_POSITION;
+				float2 texcoord : TEXCOORD0;
+				float3 cubenormal : TEXCOORD1;
+				UNITY_FOG_COORDS(2)
+			};
+
+			v2f vert (appdata v)
+			{
+				v2f o;
+				o.pos = UnityObjectToClipPos (v.vertex);
+				o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
+				o.cubenormal = mul (UNITY_MATRIX_MV, float4(v.normal,0));
+				UNITY_TRANSFER_FOG(o,o.pos);
+				return o;
+			}
+
+			fixed4 frag (v2f i) : SV_Target
+			{
+				fixed4 col = _Color * tex2D(_MainTex, i.texcoord);
+				fixed4 cube = texCUBE(_ToonShade, i.cubenormal);
+				fixed4 c = fixed4(2.0f * cube.rgb * col.rgb, col.a);
+				UNITY_APPLY_FOG(i.fogCoord, c);
+				return c;
+			}
+			ENDCG			
+		}
+	} 
+
+	Fallback "VertexLit"
+}

Assets/NatureStarterKit2/Standard Assets/Effects/ToonShading/Shaders/ToonBasic.shader.meta

@@ -0,0 +1,6 @@
+fileFormatVersion: 2
+guid: d84268709d11078d11005b9844295342
+ShaderImporter:
+  defaultTextures: []
+  userData: 
+  assetBundleName: 

Assets/NatureStarterKit2/Standard Assets/Effects/ToonShading/Shaders/ToonBasicOutline.shader

@@ -0,0 +1,68 @@
+// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
+
+Shader "Toon/Basic Outline" {
+	Properties {
+		_Color ("Main Color", Color) = (.5,.5,.5,1)
+		_OutlineColor ("Outline Color", Color) = (0,0,0,1)
+		_Outline ("Outline width", Range (.002, 0.03)) = .005
+		_MainTex ("Base (RGB)", 2D) = "white" { }
+		_ToonShade ("ToonShader Cubemap(RGB)", CUBE) = "" { }
+	}
+	
+	CGINCLUDE
+	#include "UnityCG.cginc"
+	
+	struct appdata {
+		float4 vertex : POSITION;
+		float3 normal : NORMAL;
+	};
+
+	struct v2f {
+		float4 pos : SV_POSITION;
+		UNITY_FOG_COORDS(0)
+		fixed4 color : COLOR;
+	};
+	
+	uniform float _Outline;
+	uniform float4 _OutlineColor;
+	
+	v2f vert(appdata v) {
+		v2f o;
+		o.pos = UnityObjectToClipPos(v.vertex);
+
+		float3 norm   = normalize(mul ((float3x3)UNITY_MATRIX_IT_MV, v.normal));
+		float2 offset = TransformViewToProjection(norm.xy);
+
+		o.pos.xy += offset * o.pos.z * _Outline;
+		o.color = _OutlineColor;
+		UNITY_TRANSFER_FOG(o,o.pos);
+		return o;
+	}
+	ENDCG
+
+	SubShader {
+		Tags { "RenderType"="Opaque" }
+		UsePass "Toon/Basic/BASE"
+		Pass {
+			Name "OUTLINE"
+			Tags { "LightMode" = "Always" }
+			Cull Front
+			ZWrite On
+			ColorMask RGB
+			Blend SrcAlpha OneMinusSrcAlpha
+
+			CGPROGRAM
+			#pragma vertex vert
+			#pragma fragment frag
+			#pragma multi_compile_fog
+			fixed4 frag(v2f i) : SV_Target
+			{
+				UNITY_APPLY_FOG(i.fogCoord, i.color);
+				return i.color;
+			}
+			ENDCG
+		}
+	}
+	
+	Fallback "Toon/Basic"
+}

Assets/NatureStarterKit2/Standard Assets/Effects/ToonShading/Shaders/ToonBasicOutline.shader.meta

@@ -0,0 +1,6 @@
+fileFormatVersion: 2
+guid: 9ce107479d11178d11005b9844295342
+ShaderImporter:
+  defaultTextures: []
+  userData: 
+  assetBundleName: 

Assets/NatureStarterKit2/Standard Assets/Effects/ToonShading/Shaders/ToonLit.shader

@@ -0,0 +1,53 @@
+Shader "Toon/Lit" {
+	Properties {
+		_Color ("Main Color", Color) = (0.5,0.5,0.5,1)
+		_MainTex ("Base (RGB)", 2D) = "white" {}
+		_Ramp ("Toon Ramp (RGB)", 2D) = "gray" {} 
+	}
+
+	SubShader {
+		Tags { "RenderType"="Opaque" }
+		LOD 200
+		
+CGPROGRAM
+#pragma surface surf ToonRamp
+
+sampler2D _Ramp;
+
+// custom lighting function that uses a texture ramp based
+// on angle between light direction and normal
+#pragma lighting ToonRamp exclude_path:prepass
+inline half4 LightingToonRamp (SurfaceOutput s, half3 lightDir, half atten)
+{
+	#ifndef USING_DIRECTIONAL_LIGHT
+	lightDir = normalize(lightDir);
+	#endif
+	
+	half d = dot (s.Normal, lightDir)*0.5 + 0.5;
+	half3 ramp = tex2D (_Ramp, float2(d,d)).rgb;
+	
+	half4 c;
+	c.rgb = s.Albedo * _LightColor0.rgb * ramp * (atten * 2);
+	c.a = 0;
+	return c;
+}
+
+
+sampler2D _MainTex;
+float4 _Color;
+
+struct Input {
+	float2 uv_MainTex : TEXCOORD0;
+};
+
+void surf (Input IN, inout SurfaceOutput o) {
+	half4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
+	o.Albedo = c.rgb;
+	o.Alpha = c.a;
+}
+ENDCG
+
+	} 
+
+	Fallback "Diffuse"
+}

Assets/NatureStarterKit2/Standard Assets/Effects/ToonShading/Shaders/ToonLit.shader.meta

@@ -0,0 +1,6 @@
+fileFormatVersion: 2
+guid: 48dca5b99d113b8d11006bab44295342
+ShaderImporter:
+  defaultTextures: []
+  userData: 
+  assetBundleName: 

Assets/NatureStarterKit2/Standard Assets/Effects/ToonShading/Shaders/ToonLitOutline.shader

@@ -0,0 +1,17 @@
+Shader "Toon/Lit Outline" {
+	Properties {
+		_Color ("Main Color", Color) = (0.5,0.5,0.5,1)
+		_OutlineColor ("Outline Color", Color) = (0,0,0,1)
+		_Outline ("Outline width", Range (.002, 0.03)) = .005
+		_MainTex ("Base (RGB)", 2D) = "white" {}
+		_Ramp ("Toon Ramp (RGB)", 2D) = "gray" {} 
+	}
+
+	SubShader {
+		Tags { "RenderType"="Opaque" }
+		UsePass "Toon/Lit/FORWARD"
+		UsePass "Toon/Basic Outline/OUTLINE"
+	} 
+	
+	Fallback "Toon/Lit"
+}

Assets/NatureStarterKit2/Standard Assets/Effects/ToonShading/Shaders/ToonLitOutline.shader.meta

@@ -0,0 +1,6 @@
+fileFormatVersion: 2
+guid: 054a31a99d11e49d110086ba44295342
+ShaderImporter:
+  defaultTextures: []
+  userData: 
+  assetBundleName: